; **************************************************************************
; *** catalogue de règles, valable pour l'espagnol ***
; *** source: C. Lleal ***
; *** dernière modification: 9 octobre 2000 ***
; **************************************************************************
@deffeatures
; traits grammaticaux (= priorité 0)
0 : origine := { arab, germ, celt, hebr } ; arabismes, germanismes, celticismes, hébraïsmes
0 : categorie := { verbe, subst, adj, prep, pron, conj, adv, reste } ; catégorie grammaticale
; pour les substantifs/adjectifs
0 : groupe := { gra, gro, gru, gre, grk, gri, grm, grnd, irr } ; déclinaison en a, o, u, e, i, consonantique (grk), mixte (grm), non défini (grnd) ou irrégulier (irr)
0 : cas := { nom, gen, dat, acc, abl, vok } ; nominatif, génitif, datif, accusatif, ablatif, vocatif
0 : genre := { m, f, n, mf } ; masculin, féminin, neutre, masculin ou féminin (mf)
0 : suffixe := { dim, augm } ; diminutif, augmentatif
0 : termin := { us } ; terminaison (au nominatif)
; pour les adjectifs
0 : type := { poss, card, ord } ; adjectifs possessifs, numéros cardinaux et ordinaux
0 : compar := { comp, superl } ; comparatif, superlatif (non marqué = positif)
; pour les verbes
0 : type := { amalg } ; forme amalgamée
0 : type := { dep } ; verbes déponents
0 : mode := { subj } ; subjonctif
0 : forme := { inf, ger, part, imper } ; infinitif, gérondif, participe, impératif
0 : temps := { parf, impf, pres, fut, cond } ; parfait, imparfait, présent, futur, conditionnel
0 : groupe := { are, eere, ire, ere, ser, haber, autre } ; conjugaison en a, i, e long ou e bref; auxiliaires esse, habere ou autre type de conjugaison
0 : personne := { i, ii, iii } ; i=1ère, ii=2ème, iii=3ème personne
; pour les substantifs/adjectifs/verbes/pronoms etc.
0 : nombre := { sg, pl } ; singulier, pluriel
; pour tous
0 : flexion := { invar } ; forme invariable
; traits sémantiques
0 : type := { dieu } ; noms de dieux/déesses
; traits prosodiques (= priorité 0)
0 : prosodie := { procl, encl } ; emploi proclitique/enclitique
; traits spéciaux
0 : amalgame := { rec } ; [+rec] => la forme amalgamée est à reconstruire
0 : apocope := { apoc }
; traits phonologiques (priorité >0)
; type de son
1 : type := { voc, cons, svoc, liq }
; voyelles
2 : artic := { ant, cent, post }
2 : aperture := { haut, moy, bas }
2 : aperture := { ouv, ferm }
2 : accent := { ton }
2 : longueur := { long, bref } ; ces traits sont aussi valables pour les consonnes et les liquides
; liquides
2 : vibration := { vibr, lat }
; consonnes et semivoyelles
2 : artic := { bil, ldent, ident, dent, alv, pal, vel, lar }
2 : type := { ocl, fric, nas, aprox, afr, retro }
2 : voix := { son, sourd }
@endfeatures
@deflitterals
; voyelles
ì := [ voc, haut, ant, ouv ]
í := [ voc, haut, ant, ferm ]
i := [ voc, haut, ant ]
è := [ voc, moy, ant, ouv ]
é := [ voc, moy, ant, ferm ]
e := [ voc, moy, ant ]
à := [ voc, bas, cent, ouv ]
á := [ voc, bas, cent, ferm ]
a := [ voc, bas, cent ]
ò := [ voc, moy, post, ouv ]
ó := [ voc, moy, post, ferm ]
o := [ voc, moy, post ]
ù := [ voc, haut, post, ouv ]
ú := [ voc, haut, post, ferm ]
u := [ voc, haut, post ]
; consonnes
b := [ cons, bil, ocl, son ]
ß := [ cons, bil, aprox, son ] ; ß = ASCII 225 (beta)
d := [ cons, dent, ocl, son ]
Ù := [ cons, dent, aprox, son ] ; ASCII 235 (delta)
f := [ cons, ldent, fric, sourd ]
g := [ cons, vel, ocl, son ]
h := [ cons, lar, fric, sourd ]
k := [ cons, vel, ocl, sourd ]
m := [ cons, bil, nas, son ] ; [son] n'est pas indispensable
n := [ cons, alv, nas, son ] ; [son] n'est pas indispensable
ñ := [ cons, pal, nas, son ] ; [son] n'est pas indispensable
p := [ cons, bil, ocl, sourd ]
s := [ cons, dent, fric, sourd ]
z := [ cons, dent, fric, son ]
Ç := [ cons, alv, fric, sourd ] ; Ç = ASCII 128
Õ := [ cons, alv, fric, son ] ; Õ = ASCII 229
¢ := [ cons, alv, retro, sourd ] ; ¢ = ASCII 189
t := [ cons, dent, ocl, sourd ]
§ := [ cons, dent, retro, sourd ] ; § = ASCII 245
v := [ cons, ldent, fric, son ] ; pas nécessaire
x := [ cons, vel, fric, sourd ]
Ô := [ cons, vel, aprox, son ] ; Ô = ASCII 226 (gamma)
f := [ cons, pal, fric, sourd ] ; f = ASCII 159
õ := [ cons, pal, fric, son ] ; õ = ASCII 228 (sigma, grand)
Ú := [ cons, ident, fric, sourd ] ; Ú = ASCII 233 (theta, grand)
ç := [ cons, dent, afr, sourd ]
ø := [ cons, dent, afr, son ] ; ø = ASCII 155
¶ := [ cons, pal, afr, sourd ] ; ¶ = ASCII 244
þ := [ cons, pal, afr, son ] ; þ = ASCII 231
:= [ cons, pal, aprox, son ] ; = ASCII 152
y := [ cons, pal, retro, son ]
; liquides
l := [ liq, lat ]
£ := [ liq, pal ] ; £ = ASCII 156
r := [ liq, vibr ]
; semi-voyelles (= semi-consonnes)
j := [ svoc, pal ]
w := [ svoc, vel ]
@endlitterals
@defsymbols
C := [ +cons ]
V := [ +voc ]
Y := [ +svoc, +pal ]
W := [ +svoc, +vel ]
L := [ +liq ]
N := [ +cons, +nas ]
G := [ +svoc ]
A := [ +voc, +cent, +bas ]
E := [ +voc, +ant, +moy ]
I := [ +voc, +ant, +haut ]
O := [ +voc, +post, +moy ]
U := [ +voc, +post, +haut ]
@endsymbols
@defrules
; évolution spéciale du futur
0: @[+verbe,+cond,+fut]#*?|+hA|b*?# > @[+rec]#*?!|!+# : 0) évolution spéciale du conditionnel/futur (verbes) => l'infinitif est calculé
; ******************************************************************
; *** I) époque préclassique et classique (jusqu'au IIIe siècle) ***
; ******************************************************************
; voyelles non déterminées sont marquées [+bref], cas spécial: au > a[+bref]u
V[-long,-bref] > V[+bref] : voyelles non déterminées sont marquées [+bref]
C+ > { C, C[+long] } : 0.4) consonnes devant frontière de morphème sont marquées [+long] (ex: aquel, aquesta), tendance
; changements grammaticaux / morphologiques
@[+verbe,+inf]#*e1[+bref]re2# > { @*e[+long]&1re2, @*i[+long]&1re2 } : 0.5) Verbes -e[+bref]re > -e[+long]re ou -i[+long]re
@[+verbe,+cond,+fut]#*e1[+bref]re2# > { @*e[+long]&1re2, @*i[+long]&1re2 } : 0.5) Verbes -e[+bref]re > -e[+long]re ou -i[+long]re
@[+subst,+gru,+n,+acc,+pl]#*a1# > { @[+gro,+m]#*o[+bref]s&1, @*a1 } : 0.61) Subst. neutres avec -a au pluriel > subst. masc. -os
@[+subst,+gro,+n,+acc,+pl]#*a1# > { @[+m]#*o[+bref]s&1, @*a1 } : 0.62) [+n] -a > [+m] -os
@[+subst,+n,+grk,+us]#*us1# > @[-us,+gro,+m]*um&1 : 0.63) changement grammatical: neutre > masculin
@[+subst,+n,+grk]#*us1# > @[+gro,+m]*um&1 : 0.64) changement grammatical: neutre > masculin
@[+subst,+gre,+acc,+sg,+f]#*e1m# > @[+gra,+f]*a&1m : 0.71) changement de groupe de déclinaison, genre
@[+subst,+gre,+acc,+sg]#*e1m# > @[+gra]*a&1m : 0.72) changement de groupe de déclinaison, genre
@[+subst,+gre,+acc,+pl,+f]# * e1[+long]s# > @[+gra,+f] * a&1s# : 0.73) changement du groupe déclinaison: es > as
@[+subst,+gre,+acc,+pl]# * e1[+long]s# > @[+gra] * a&1s# : 0.74) changement du groupe déclinaison: es > as
@[+verbe,+ere,+inf,+pres]#*E1[-long]rE2# > { @*I[+long]&1rE2, @*E[+long]&1rE2 } : 0.81) changement du groupe de conjugaison (=> régularisation)
@[+verbe,+ere,+cond,+fut]#*E1[-long]rE2# > { @*I[+long]&1rE2, @*E[+long]&1rE2 } : 0.82) changement du groupe de conjugaison (=> régularisation)
@[+n] > @[+m] : 0.83) les neutres qui n'ont pas encore été transformés deviennent [+m]
i[+long]w1i[+bref].&# > i&1i.& : 0.9) le w tombe dans les parfaits des verbes (en partie déjà en LC)
h1 > &1 : 1) perte de l'aspiration
?|.m1# > ?.&1 : 2a) chute de nasale finale
n1s > &1s : 2b) chute de nasale
; accent tonique
@#* V[-ton].&|.V[-ton].&|L[+long].V[-ton].&# > @*V.&.V[+ton].&L.V.& : 3*) accent tonique (trois ou plus de syllabes, pénultième = longue)
@#. V[-ton].&# > @.V[+ton].& : 3*) accent tonique (monosyllabes)
@#* V[+long, -ton].&|.V.&# > @* V[+ton].&.V.& : 3a) accent tonique (deux ou plus de syllabes)
@#. V[-ton].&|.V[-ton].&# > @#.V[+ton].&.V.&# : 3a*) accent tonique (disyllabes)
@#* V[+bref, -ton]L|.V[-ton].&# > @* V[+ton]L.V.& : 3b') accent tonique (syllabe fermée)
@#* V[+bref, -ton]C|.V[-ton].&# > @* V[+ton]C.V.& : 3b") accent tonique (syllabe fermée)
@#* V[+bref, -ton].&|C[+long].V[-ton].&# > @* V[+ton].&C.V.& : 3b"') accent tonique (géminées)
@#* V[-ton].&|.V[-long,-ton].&|.V[-ton].&# > @* V[+ton].&.V.&.V.& : 3c') accent tonique
; perte de la durée, phonologisation de l'aperture
V[-bas, +long] > V[-long, +ferm] : 4a) perte de la durée, phonologisation de l'aperture
V[-bas, +bref] > V[-bref, +ouv] : 4b) perte de la durée, phonologisation de l'aperture
V[+bas, +long] > V[-long] : 4c') perte de la durée, phonologisation de l'aperture
V[+bas, +bref] > V[-bref] : 4c") perte de la durée, phonologisation de l'aperture
Vm1|kV > Vn&1kV : 4.2) assimilation du m
Vm1|kwV > Vn&1kwV : 4.3) assimilation du m
@#*a[+ton]|wI1t# > @*a!|w&1t : 4.5) évolution de la 3ème pers. du parfait (verbes)
@#*a[+ton]w1t# > @*au&1t : 4.6) vocalisation de w (verbes)
@#*a1[+ton]u2t# > @*ó[+ton]t : 4.7) monophtongaison de au (verbes)
V[+ton].&|.V[-ton]C[+ocl]LV > V[-ton].&.V[+ton]CLV : 5i) déplacement de l'accent tonique
V[+haut, +ton]|V.&|.V.&# > V[-ton]V[+ton].&.V.& : 5ii) déplacement de l'accent tonique
U1[+ton]|I[-ton] > { U1 I, w&1!| I[+ton] } : 5.51) déplacement de l'accent tonique, u > w (tendance)
E[+ton]|V[-ant] > { EV, E[-ton] V[+ton] } : 5.52) déplacement de l'accent (tendance)
I[+ton]|A[-ton] > { IA, I[-ton]A[+ton] } : 5.53) déplacement de l'accent (tendance)
@#sC > @ìs|C : 6) ì prostétique
; confusion des préfixes per- / por-
@#prO# > @pO!#r# : 6.51) métathèse de pro, croisement avec per (déjà en LV, Penny, 219)
@#prO|+ > { @pO!|!+r|+, @prO } : 6.52) métathèse de pro, croisement avec per (déjà en LV, Penny, 219)
@#prO|!+ > { @pO!|r|, @prO } : 6.53) métathèse de pro, croisement avec per, tendance (déjà en LV, Penny, 219)
@#pE1[-ton]r > { @pE1r, @pO&1r } : 6.54) confusion entre les prefixes per/por (< pro), tendance
@#pE1[+ton]r > { @pE1r, @pO[+ton]&1r } : 6.55) confusion entre les prefixes per/por (< pro), tendance
; monophtongaison de oe/ae
O1[+ton]!|E2[+ton] > { é[+ton]&1&2, è[+ton]&1&2 } : 7a') monophtongaison de oe
O1!|E2 > { é&1&2, è&1&2 } : 7a") monophtongaison de oe
A1[+ton]!|E2[+ton] > { é[+ton]&1&2, è[+ton]&1&2 } : 7b') monophtongaison de ae
A1!|E2 > { é&1&2, è&1&2 } : 7b") monophtongaison de ae
; fermeture de la voyelle en hiatus
V[+moy,+ant,-ton] V[-ant] > V[+haut,+ferm] V : 8.1') fermeture de la voyelle en hiatus
V[+moy,+post,-ton] V[-post] > V[+haut] V : 8.1") fermeture de la voyelle en hiatus
@[+procl,+encl]#* V[+moy,+ant,+ton] V[-ant] > @* V[+haut,+ferm] V : 8.2') fermeture de la voyelle en hiatus (mots enclitiques/proclitiques)
@[+procl,+encl]#* V[+moy,+post,+ton] V[-post] > @* V[+haut,+ferm] V : 8.2") fermeture de la voyelle en hiatus (mots enclitiques/proclitiques)
; métaphonies
I[+ouv].&|.I[+ferm].&# > { I.&.I.&, I[+ferm].&.I.&# } : 8.51) métaphonie, tendance (assimilation)
E1.&|.I2[+ferm].&# > { E1.&.I2.&, E1[+haut,+ferm].&.I2.&# } : 8.52) métaphonie, tendance (assimilation)
V[+moy,+ferm].&|.It# > V[+haut].&.It : 8.53) analogie à la 1ere personne (ou le í final fait passer e à í par métaphonie) (verbes)
I1[-ton] V2 > j&1!|V2 : 9i) formation de dipthongues croissantes: i > j (perte d'une syllabe)
U1[-ton] V2 > w&1!|V2 : 9ii) formation de diphtongues croissantes: u > w (perte d'une syllabe)
AU1 > Aw&1 : 9.7) deuxième élément de la diphtongue se transforme en wau
@[+verbe]#*A[+ton]|wI1t# > @*A!|w&1t : 9.8) chute de la voyelle finale dans les parfaits des verbes en are
V[+ant,+haut,+ouv] > V[+moy,+ferm] : 10) ouverture de la voyelle antérieure
U1L2N > U1u&2N : 10.1) vélarisation du l
U1u2N > U1[+ferm]&2N : 10.2) assimilation complète du 2e u, fermeture du premier u
@[+dep] > @[-dep] : 10.3) les verbes déponents se perdent
@[+arab]#al|+wV > @algwV : 10.51) mots arabes: insertion d'une consonne d'appui (g) devant wV
?|+w1V > ?ß&1V : 10.52) (cf. R12) semivoyelle passe à fricative après frontière de morphème (mots composés)
; chute de wau
V[+ton]LC[-vel, -son] w1 V > VLC&1V : 11i') chute de wau
V[+ton]C[+long] w1 V > VC&1V : 11i") chute de wau
V[+ton] w1 V[+post, +haut] > { V&1V, Vw1V } : 11ii) chute de wau (tendance)
V[+cent]w1V[+moy,+ant] > { V&1V, Vw&1V } : 11.1) chute de wau (tendance)
Vb1V > { V&1V, Vb1V } : 11.2) chute de b intervocalique (tendance)
Cw1V[+post] > C&1V : 11.3) chute de wau
; bilabialisation de wau / sonorisation de b
@#w1V > @ß&1V : 12') bilabialisation de wau
@#w1LV > @ß&1LV : 12") bilabialisation de wau
@#w1GV > @ß&1GV : 12"') bilabialisation de wau
Lw1V > Lß&1V : 12"") bilabialisation de wau
Lw1LV > Lß&1LV : 12""') bilabialisation de wau
Lw1GV > Lß&1GV : 12""") bilabialisation de wau
V|w1V > Vß&1V : 12"""') bilabialisation de wau (pas dans AU| > aw|)
V|w1LV > Vß&1LV : 12"""") bilabialisation de wau (pas dans AU| > aw|)
V|w1GV > Vß&1GV : 12""""') bilabialisation de wau (pas dans AU| > aw|)
Vb1V > Vß&1V : 13') sonorisation de b
Vb1LV > Vß&1LV : 13") sonorisation de b
Vb1GV > Vß&1GV : 13"') sonorisation de b
V[+ouv].&|?.wV > V[+ferm].&?.wV : 13.5) le wau agit sur la syllabe précédente, tendance
; *******************************************************************
; *** II) le bas empire (III-IVe siècle) ***
; *******************************************************************
300: V[+post,+haut,+ouv]*V > V[+moy,+ferm]*V : 14) ouverture de la voyelle postérieure en position non finale
V[+ouv, -ton] > V[-ouv] : 15') neutralisation de la distinction [+ouv]/[+ferm] dans les voyelles atones
V[+ferm, -ton] > V[-ferm] : 15") neutralisation de la distinction [+ouv]/[+ferm] dans les voyelles atones
a1[-ton]|a2 > &1!|a2 : 16') fusion vocalique
e1[-ton]|e2 > &1!|e2 : 16") fusion vocalique
i1[-ton]|i2 > &1!|i2 : 16"') fusion vocalique
o1[-ton]|o2 > &1!|o2 : 16"") fusion vocalique
u1[-ton]|u2 > &1!|u2 : 16""') fusion vocalique
C[-nas,-liq,-long] G > C[+long] G : 17i) allongement de la consonne en contact avec yod ou wau en contacto con yod/wau
G C1[-nas,-liq,-long] > G C1[+long] : 17ii) allongement de la consonne en contact avec yod ou wau
V1[+ton].&|C[+vel]V2[-bas]|LV.&# > V1.&C&2!|LV.& : 17.2') syncope latine (cf. Penny 84)
V1[+ton].&|C[+dent]V2[-bas]|LV.&# > V1.&C&2!|LV.& : 17.2") syncope latine (cf. Penny 84)
Vt1lV > { Vk&1lV, V!|l|d&1V } : 17.3) <= R21) vélarisation ou métathèse (et sonorisation) de la consonne dentale (Penny 87)
@#.&|+ > { @., @.&!+ } : 17.4) effacement éventuel de la frontière de morphème (mot est perçu comme une seule unité lexicale)
@#.V|rV|klV.&# > { @.VrVklV.&, @.VlVkrV.& } : 18.5) méthathèse r-l, tendance
VC[+ocl,+vel,+son]?[+cons,+liq]V > VC[+aprox]?V : 17.51) <= R22i) affaiblissement des occlusives vélaires
VC[+ocl,+vel,+sourd,-fric]?[+cons,+liq,-vibr]V > VC[+fric]?V : 17.52) <= R22ii) affaiblissement des occlusives vélaires ([-vibr] pas chez Lleal => alacrem)
@#.&|C[+dent,+fric]V1[-bas,-ton].&|C[+dent,+ocl]V[+ton] > @.&!|C&1.&CV : 17.61) <= 19') syncope des voyelles prétoniques non initiales
@#.Vm|pV1[-bas]|tV[+ton].&|? > @.Vm!|p&1tV.&? : 17.62) <= 19.3) syncope mp't, prétonique
V!+C[-long,-afr,-son,-vel]!+V > VC[+son]V : 17.71) <= R44i) sonorisation des sourdes intervocaliques
V!+C[-long,-afr,-son,-vel]!+LV > VC[+son]LV : 17.72) <= R44ii) sonorisation des sourdes intervocaliques
V!+C[-long,-afr,-son,+vel,-fric]!+V[-ant] > VC[+son]V : 17.73) <= R44i) sonorisation des sourdes intervocaliques
V!+C[-long,-afr,-son,+vel,-fric]!+LV > VC[+son]LV : 17.74) <= R44ii) sonorisation des sourdes intervocaliques
V!+C[-long,-afr,-son,+vel,+dent,-fric]wV[-ant] > VC[+son]wV : 17.75) <= R44*) sonorisation des sourdes en position V -- wA
Vv1V > Vß&1V : 17.76) bilabialisation de v (après sonorisation)
V1[+ton].&|.w2V3[-bas].&|.V > V1.&!|.&2&3.&.V : 18.11) syncope des voyelles posttoniques internes (pas chez Lleal; "sangre")
V1[+ton].&|L[-long].V2[-bas].&|.V3 > V1.&!|L.&2.&.V3 : 18.12) syncope des voyelles posttoniques non finales
V1[+ton]|.V2[-bas].&|L > V1.&2.&!|L : 18.13) syncope des voyelles posttoniques non finales
V1[+ton]m|bV2|?[+cons,+liq] > V1m!|b|&2? : 18.14) <= R59ii*) syncope posstonique
V1m|bV2|?[+cons,+liq]V[+ton] > V1m!|b|&2?V : 18.15) <= R59ii*) syncope prétonique
V[-ton]|L[-long]V1[-cent,-ton]|C[+dent]V|.V.&|.V[-ton].&# > V!|L&1CV.V.&.V.& : 18.16) syncope des voyelles prétoniques
@#.&|LV1[-bas,-ton]|C[+dent,+ocl]V[+ton] > @.&!|L&1CV : 19.1) syncope des voyelles prétoniques non initiales
@#.&|LV1[-bas,-ton]|C[+vel]V[+ton] > @.&!|L&1CV : 19.2) syncope
@#.&|LV1[-bas,-ton]|C[+nas]V|L[+long]V[+ton] > @.&!|L&1CVLV : 19.3) syncope des voyelles prétoniques non initiales
V|nrV > V!|n|rV : 19.5) correction de la structure syllabique après syncope
C1[+ocl] C2[+dent,+fric] C3[+ocl] > &1 C2 C3 : 20i) simplification de groupes consonantiques
N C1[+ocl] C2[+ocl] > N &1 C2 : 20ii) simplification de groupes consonantiques
C1[+ocl] C2[+dent, +ocl] j > &1 C2 j : 20iii) simplification de groupes consonantiques
VC[+ocl,+vel,+son]LV > VC[+aprox]LV : 22i') affaiblissement des occlusives vélaires
Vp1tV > V&1t[+long]V : 23i) assimilation consonantique
Vp1sV > V&1s[+long]V : 23ii) assimilation consonantique
Vd1C[+bil,-nas]V > V&1C[+long]V : 23iii) assimilation consonantique
Vr1sV > V&1s[+long]V : 23iv) assimilation consonantique
Vm1nV > V&1n[+long]V : 23v) assimilation consonantique
Vn1!+fV > V&1f[+long]V : 23vi) assimilation consonantique
Vk1s| > Vx&1s : 23.1) assimilation consonantique
Vk1s# > Vx&1s : 23.2) assimilation consonantique
@#.V1|mV3|nV4[+ton]|.V5.&6# > @.V1!|m&3nV4.V5.&6 : 23.5) syncope des voyelles prétoniques internes (cf. R19)
V[+bas,+ton]|CV1[+ant,-haut]r > VCa&1r : 24) ouverture conditionnée de e (tendance)
@[-conj]#*V1r2# > { @*V1r2, @*V1|r!#V1[-ton]&2 } : 25) copie vocalique (tendance)
@#V[+bas] w1 C[+dent,+fric] C[+vel] > @V&1 C C : 26') chute du wau due à l'assimilation des vélaires
@#V[+bas] w1 C[+vel] > { @Vw1C, @V&1 C } : 26") chute du wau due à l'assimilation des vélaires, *tendance
@#a1s > { @a1s, @e&1s } : 26.1) confusion des préfixes a(b)(s)/ex, tendance
t[+long]j > çj : 27) t se transforme en affriquée par influence du yod
C[+vel,+sourd,+long]j > C[+pal,+afr]j : 28) palatalisation de la consonne vélaire sourde
; *******************************************************************
; *** période visigoth (V-VIII siècle) ***
; *******************************************************************
500: @#L[+vibr,-long] > @L[+long] : 29) renforcement de la liquide initiale
V C[+ocl, +son] L V > V C[+aprox] L V : 30') affaiblissement des occlusives sonores
V C[+ocl, +son] V > V C[+aprox] V : 30") affaiblissement des occlusives sonores
V C1[+vel, -ocl] l > V j&1 l : 31') transformation en yod de x / Ô
V C1[+vel, -ocl] n > V j&1 n : 31") transformation en yod de x / Ô
k1!+ V[+ant] > ¶&1 V : 32) palatalisation de la consonne vélaire sourde
Vd1¶V > V&1¶V : 32.5) assimilation du d
@#wV > @gwV : 33) insertion d'un g prostétique
; C[+vel] w1 V[-bas] > { C &1 V, Cw1V } : 34) chute du wau (tendance)
Vd1|tV > { V&1t[+long]V, Vs&1tV } : 34.5) assimilation ou dissimilation du groupe dt intervocalique
C[+dent,+fric,+sourd] > C[+alv] : 35) transformation de s dental en s alvéolaire
V[+moy,+ouv].&|.j > V[+ferm].&.j : 35.5) <= R51) le yod ferme la syllabe précédente, tendance
C[+afr] j1 > { C &1, C j1 } : 36) assimilation du yod premier, tendance
C C2[+dent,+sourd]# > C &2 : 37a) chute des occlusives finales
V C1[+vel, +sourd]# > V &1 : 37b) chute des occlusives finales
?L[-vibr,-pal]j > ?L[+pal]j : 38i) palatalisation de l (pas au début d'un mot)
n[-pal]j > n[+pal,-long]j : 38ii) palatalisation de n
jL[-vibr,-pal]!| > jL[+pal] : 38iii) palatalisation de l
jn[-pal]!| > jn[+pal,-long] : 38iv) palatalisation de n
rj1V[+ant,-haut,+ton] > r&1V[+ferm] : 39i) réduction de la diphtongue palatale tonique (-> Penny 56)
C[-dent]j1V[+ant, -haut, +ton] > C&1V : 39ii) réduction de la diphtongue palatale tonique
? C[-bil,-ldent,+son,+long]j > ? C[+pal,+afr,-long]j : 40) transformation en affriquée de d/g par influence de la yod (pas au début d'un mot (pas chez Lleal))
V[+moy,+ferm,+ton]C[+long]Lj > V[+haut,+ferm]CLj : 41i) le yod ferme la syllabe précédente
V[+moy,+ferm,+ton]C[+long]j > V[+haut,+ferm]Cj : 41ii) le yod ferme la syllabe précédente
V[+moy,+ferm,-ton]C[+long]Lj > V[+haut,-ferm]CLj : 41i') le yod ferme la syllabe précédente
V[+moy,+ferm,-ton]C[+long]j > V[+haut,-ferm]Cj : 41ii") le yod ferme la syllabe précédente
C[+vel,+son]V[+ant] > C[+pal,+afr]V : 42) palatalisation des vélaires sonores
C[+vel] w1 V[-bas] > { C &1 V, Cw1V } : 42.5) <= R34) chute du wau (tendance)
C[+pal,+afr,+son]j1 > C&1 : 43) assimilation du yod
kw1a# > { kw1a, k&1a } : 44.5) perte du wau devant a à la fin du mot (tendance)
l[+long] C > l[-long] C : 44.6) simplification du groupe ll'C
@[+subst,+f]#A1[-ton]|C > @&1!|C : 44.8) aphérèse due à l'emploi de l'article (illa_apotheca => illa (a)potheka)
C[-nas,+long] > C[-long] : 45) perte de la longueur pour les consonnes
; *******************************************************************
; *** castillan médiéval (siècles VIII-XII) ***
; *******************************************************************
800: L[+lat, +long] > L[-long,-lat,+pal] : 46i) palatalisation de ll
N[+alv,+long] > N[-long,+pal] : 46ii) palatalisation de nn
VC1[+bil,+son,-nas]j > { V&1j, VC1j } : 47) assimilation eventuelle des bilabiales
Vl1V*Vl2[+long]V > { Vl1V*Vl2V, Vr&1V*Vl2V } : 47.5) dissimilation de l-ll (p.ex. calamillu)
VC1[-bil,-ldent,+aprox]r > { V!|j|&1r, VC1r } : 48) transformation en yod des consonnes affaiblies; tendance, voir Penny 82
E[+ouv]N > { EN, E[+ferm]N } : 48.3) fermeture eventuelle devant nasale
@[+procl,+encl,-conj,-prep]#*?[-voc,-ant,-moy]V1[+ant,+moy,+ouv,+ton] > { @*?V1[+ferm], @*?V1[+ferm,-ton]!|!#V1 } : 48.51) dédoublement de e, très rare dans les mots proclitiques
@[+procl,+encl,-conj,-prep]#V1[+ant,+moy,+ouv,+ton] > { @V1[+ferm], @V1[+ferm,-ton]!|V1 } : 48.52) dédoublement de e, très rare dans les mots proclitiques
@[+procl,+encl,+conj,+prep]#*E[+ouv,+ton] > @*E[+ferm] : 48.53) évolution de è proclitique / enclitique dans les prépositions / conjonctions
@[-encl,-procl]#*?[-voc,-ant,-moy,-ferm] V1[+ant,+ouv,+ton] > @* ? V1[+ferm,-ton]!| V1 : 49i) dédoublement de e (premier pas de la diphongaison)
@[-encl,-procl]#V1[+ant,+ouv,+ton] > @ V1[+ferm,-ton]!| V1 : 49ii) dédoublement de e (premier pas de la diphongaison)
?C1[+pal,+afr,+son] > ?j&1 : 50) affaiblissement des affriquées palatales
AE[+ton] > { AE, A[+ton]E[-ton] } : 50.3) déplacement éventuel de l'accent sur la syllabe plus ouverte
@#.V1.&2|jV3[-bas]|C[+dent]V4[+ton] > @.V1.&2!|j&3|CV4 : 50.51) syncope des voyelles prétoniques internes (cf. R18)
@#.V1[+ton].&2|jV3[-bas]|C[+dent]V4 > @.V1.&2!|j&3|CV4 : 50.52) syncope des voyelles prétoniques internes (cf. R18)
V[+post, +ouv, +ton]jL[+pal] > V[+ferm]jL : 51ai) le yod agit sur la syllabe précédente
V[+post, +ouv, +ton]L[+pal]j > V[+ferm]Lj : 51aii) le yod agit sur la syllabe précédente (FAUX chez Lleal ?!)
V[+post,-ouv]jC[+nas,+pal] > V[+haut]jC : 51bi) le yod agit sur la syllabe précédente
V[+post,-ouv,-haut]C[+nas,+pal]j > V[+haut]Cj : 51bii) le yod agit sur la syllabe précédente
C1[+vel,+fric] C2[+dent,+ocl] > j&1 C2[+retro] : 52i) transformation en yod de la vélaire
C1[+vel,+fric] C2[+alv,+fric] > j&1 C2[+retro] : 52ii) transformation en yod de la vélaire
w1V.&|.jV > &1V.&.jV : 52.5) dissimilation de wau dans w-j
V|L[+vibr]G > V!|G|L : 53i) métathèse de yod / wau
V|C[+bil,-son]G > V!|G|C : 53ii) métathèse de yod / wau
V|C[+alv,+fric]G > V!|G|C : 53iii) métathèse de yod / wau
V|C[+dent]W > V!|W|C : 53.1) métathèse de wau
V|C[+vel,+ocl]W > V!|W|C : 53.2) métathèse de wau
VwC[+dent,+sourd]V > VwC[+son]V : 53.5) sonorisation de d ou ç après métathèse (=> R53)
V[+moy,+post,-ouv]C[+bil,+son]jV > V[+haut]CjV : 54aii') le yod agit sur la syllabe précédente
V[+moy,+post,-ouv]jV > V[+haut]jV : 54aii") le yod agit sur la syllabe précédente
V[+moy,+ouv]C[+bil,+son]jV > V[+ferm]CjV : 54ai') le yod agit sur la syllabe précédente
V[+moy,+ouv]jV > V[+ferm]jV : 54ai") le yod agit sur la syllabe précédente
V[+moy,+ant,-ouv]C[+bil,+son]jV > V[+haut]CjV : 54b) le yod agit sur la syllabe précédente
V[+bas,+ton]j1V[+ant,+moy] > V&1V : 56a) chute ou assmiliation de la yod
V[+ant,+haut,+ton]j1C[+ocl,+retro,-alv] > V&1C[-retro] : 56b) chute ou assmiliation de la yod ("dent" supprime)
V[+ton].&|.V[+ant].&|.C1[+dent,+aprox]V.&# > { V.&.V.&.C1V.&, V.&.V.&.&1V.& } : 57) chute des fricatives (tendance)
V1[+ton]|V2[+ant] > { V1!|&2, V1V2 } : 58i) assimilation éventuelle de la voyelle en hiatus
V1[+ton].&|.E2V[+post,+cent] > V1.&.j&2!|V : 58ii) transformation en yod de la voyelle en hiatus
@#.&|.V[+cent]|E1.&|.V[+ton] > @.&.V!|&1.&.V : 58.5) syncope / assimilation de e interne en hiatus
V[+ton]|C V1[-bas].&|? > V!|C &1!|.&? : 59i) syncope des voyelles prétoniques / posttoniques internes
V[+ton]C[+nas]|C V1[-bas].&|? > VCC&1.&!|? : 59ii) syncope des voyelles prétoniques / posttoniques internes
V[+ton]|L V1[-bas]|CV > V!|L&1CV : 59iii) syncope des voyelles prétoniques / posttoniques internes
V1|!+?[+cons,+ocl]V2[-bas]|?[+liq,-pal]V3[+ton]| > V1?&2!|?V3 : 59iv) 1syncope prétonique
V1|!+?[+cons,+dent,+bil,+vel,-fric,-nas]V2[-bas]|?[+liq,-pal]V3[+ton]| > V1?&2!|?V3 : 59iv) 2syncope prétonique
V1|!+?[+cons,+liq,-ocl]V2[-bas]|?[+liq,-pal]V3[+ton]| > V1!|?&2?V3 : 59iv) 3syncope prétonique
V1|!+?[+cons,+liq,-long]V2[-bas]|?[+cons]V3[+ton]|> V1!|?&2?V3 : 59v) syncope prétonique
V1j|?[+cons,+liq]V2[-bas]|?[+cons,+liq]V3[+ton]| > V1j!|?&2?V3 : 59vi) syncope prétonique
@#.Vm|C[+ocl]V1[-bas]|LV[+ton].&|? > @.VmC&1!|LV.&? : 59vii) syncope mp'r, prétonique
@#.V[+ton]m|pV1[-bas]|rV > @.Vmp&1!|rV : 59viii) syncope mp'r, posttonique
L[+vibr,+long]C > L[-long]C : 59.5) perte de la longueur
V[+post,+moy]L1[+lat]C[+dent,+ocl,-son] > Vj&1C : 60) transformation de l en yod
Vm1n2V > { V&1&2n[+long]V, Vm1r&2V} : 60.5) assimilation / dissimilation des groupes consonantiques secondaires
N[+alv,+long] > N[-long,+pal] : 60.7) palatalisation de n[+long] issu d'un groupe secondaire (par assimilation)
V[+bas]L1[+lat]C[+ocl,+afr] > { Vw&1C, VL1C } : 61) vélarisation des liquides latérales, tendance
V[+bas,+ton]!|j > V[+moy,+ant,+ouv]j : 62a) le yod agit sur la voyelle précédente (assimilation)
V[+bas,+ton]!|w > V[+moy,+post,+ouv]w : 62b) le wau agit sur la voyelle précédente (assimilation)
V[+bas]!|j > { V[+moy,+ant,+ouv]j, Vj } : 62a') le yod agit sur la voyelle précédente (assimilation), tendance
V[+bas]!|w > { V[+moy,+post,+ouv]w, Vw } : 62b') le wau agit sur la voyelle précédente (assimilation), tendance
V[+moy,+post,+ferm]!|G > V[+haut]G : 63b) le yod/wau agit sur la voyelle précédente (assimilation)
V[+moy,+ouv]!|G > V[+ferm]G : 63a) le yod/wau agit sur la voyelle précédente (assimilation)
V[+moy,+post,-ouv,-ferm]!|G > V[+haut]G : 63.1) le yod / wau agit sur la voyelle précédente
U W1 > U &1 : 63.5) assimilation de wau
E1[+ferm] E2[+ferm,+ton] > E1[+ton]&2 : 64) fusion vocalique
V1[+ant,-ouv,-ton] V2[+ant,+ouv,+ton] > j V1[+ant,+ferm,+ton]&2 : 65) diphtongaison de la voyelle dédoublée
@#*?mjé[+ton]n|te# > { @*?mjénte, @*?mjéntre } : 65.3) forme -mientre par analogie à domientre (< dum interim) (seulement au moyen âge)
j1é2[+ton]V > { í[+ton]&1&2V, j&1&2!|V[+ton,+ferm] } : 65.5) simplification de la triphtongue
@[+verbe]#*VC1[+aprox,-alv,-pal]V[+ton]!# > { @*VC1V, @*Vj&1V } : 65.7) <= R85) chute des fricatives, insertion d'un yod, verbes (tendance)
@[-verbe]#*VC1[+aprox,-alv,-pal]V!# > { @*VC1V, @*V&1V } : 65.7) <= R85) chute des fricatives (tendance)
@[-gru]#*V[+post,+haut,+ouv,+ton].&# > @*V[+moy,+ferm].& : 66') ouverture de la voyelle finale
@[+subst,+gru]*V[+post,+haut,-ferm,-ton].&# > { @*V[+moy,-ouv].&, @*V.& } : 66") substantifs du groupe u: dans quelques cas, u final reste u
@[-gru]#*V[+post,+haut,-ferm,-ton].&# > @*V[+moy,-ouv].& : 66"') ouverture de la voyelle finale
V[+ant,+haut,-ferm,-ton].&# > V[+moy,-ouv].& : 66"") ouverture de la voyelle finale
j1Vj2 > &1Vj2 : 66.1) dissimilation totale de j dans j-j
@[+subst]#.O1[+ton]L|C[-vel,-nas].O2.&# > { @.O1LC.O2.&, @.O1LC.e&2.& } : 66.21) dissimilation de la voyelle finale (comme dans golpe, goldre, molde, rolde, doble), tendance
@[+subst]#.O1[+ton].&|CLO2.&# > { @.O1.&CLO2.&, @.O1.&CLe&2.& } : 66.22) dissimilation de la voyelle finale (comme dans golpe, goldre, molde, rolde, doble), tendance
@[+procl,-prep,-verbe]#*.V[+ton].&|V1# > { @*.V.&V1, @*.V.&!|&1 } : 66.51) apocope due à l'emploi proclitique du mot (tendance)
@[+procl,+encl,-prep,-verbe]#.1V2.3&4|LV5[-ton,-bas].&# > { @.1V2.3&4!|L&5&, @.1V2.3&4LV5.&, @&1&2&3&4!|!+LV5[+ton,+ferm].& } : 66.52) aphérèse ou apocope des mots proclitiques / enclitiques (tendance)
@[+procl,+encl,-prep,-verbe]#.1V2.3&4|LV5[-ton,+bas].&# > { @.1V2.3&4!|L&5&, @.1V2.3&4LV5.&, @&1&2&3&4!|!+LV5[+ton].& } : 66.53) aphérèse ou apocope des mots proclitiques / enclitiques (tendance)
@[+procl,+encl,-prep,-verbe]#.1V2.3&4|C6[+ocl]V5[-ton].&# > { @.1V2.3&4!|&6&5&, @.1V2.3&4C6V5.&, @&1&2&3&4!|!+C6V5[+ton].& } : 66.54) aphérèse ou apocope des mots proclitiques / enclitiques (tendance)
@[+procl,+encl,-prep,-verbe]#.1V2.3&4|N6V5[-ton].&# > { @.1V2.3&4!|N6&5&, @.1V2.3&4N6V5.&, @&1&2&3&4!|!+N6V5[+ton].& } : 66.55) aphérèse ou apocope des mots proclitiques / enclitiques (tendance)
V[+post,+moy,+ouv] C[+nas] > { V[+ferm]C, VC } : 67) fermeture eventuelle de o devant nasale (tendance)
@[+procl,+encl]#*?[-post,-moy]V1[+post,+moy,+ouv] > { @*?V1[+ferm], @*?V1[+ferm,-ton]!|V1 } : 68') dédoublement de o dans quelques mots proclitiques / enclitiques
@[-encl,-procl]#*?[-post,-moy]V1[+post,+ouv,+moy,+ton] > @*?V1[+ferm,-ton]!|V1 : 68") dédoublement de o
@[-encl,-procl]#V1[+post,+ouv,+ton,+moy] > @V1[+ferm,-ton]!|V1 : 68"') dédoublement de o
C[+pal,+afr,+sourd] > C[+dent] : 69i) dépalatalisation de l'affriquée palatale sourde
C[+pal,+afr,+son] > C[+fric] : 69ii) fricativisation de l'affriquée palatale sonore
Ç1Vç2V > ç&1Vç2V : 69.5) assimilation de Ç dans Ç-ç
@#.I1.&|.I2[+ton].&|.V3.&# > { @.I1.&.I2.&.V3.&, @.e&1.&.I2.&.V3.& } : 69.7) dissimilation, tendance (cf. vicinus)
VC1[+bil,+nas]!+C2[+bil,+ocl,+son]V > VC1[+long]&2V : 70) assimilation des bilabiales
C[+long] > C[-long] : 71) perte de la longueur
j C[+alv,-son,+retro]!# > j C[+pal,+fric] : 72i) palatalisation de s retroflexe
j C[+alv,-son,+retro]# > j C[+alv,+fric] : 72ii) palatalisation de s retroflexe
V1[+post,-ouv,-ton]V2[+post,+ouv,+ton] > w&1 V2[+ant,+ferm] : 73) diphtongaison de o dédoublé
@#f1V > @h&1V : 74') aspiration de f initial
@#f1jV > @h&1jV : 74") aspiration de f initial
?|+f1V > ?h&1V : 74"') aspiration de f après frontière de morphème (=> mots composés)
?|+f1jV > ?h&1jV : 74"") aspiration de f après frontière de morphème (=> mots composés)
L1[+pal]j > C[+pal,+fric,+son]&1j : 75') fricativisation de la liquide palatale
jL1[+pal] > jC[+pal,+fric,+son]&1 : 75") fricativisation de la liquide palatale
j1C2[+dent,+ocl,-son]j3 > C[+pal,+retro,+son]&1C2[+retro]j3 : 76i) yod et dentales deviennent rétroflexes
j1C2[+dent,+ocl,-son]V > C[+pal,+retro,+son]&1C2[+retro]V : 76ii) yod et dentales deviennent rétroflexes
j1C2[+dent,+retro]V > C[+pal,+retro,+son]&1C2V : 76iii) yod et dentales deviennent rétroflexes
@#C[+bil,-son]L[+lat] > { @CL[-lat,+pal], @CL } : 77') palatalisation des liquides; dans quelques cas, le groupe reste intact (Penny 70)
@#C[+vel,+ocl,-son]L[+lat] > { @CL[-lat,+pal], @CL } : 77") palatalisation des liquides; dans quelques cas, le groupe reste intact (Penny 70)
@#C[+ldent,+fric,-son] L[+lat] > { @CL[-lat,+pal], @CL } : 77"') palatalisation des liquides; dans quelques cas, le groupe reste intact (Penny 70)
C[+alv,+fric]C[+bil,-son]L[+lat] > { CCL[-lat,+pal], CCL } : 77"") palatalisation des liquides; dans quelques cas, le groupe reste intact (Penny 70)
C[+alv,+fric]C[+vel,+ocl,-son]L[+lat] > { CCL[-lat,+pal], CCL } : 77""") palatalisation des liquides; dans quelques cas, le groupe reste intact (Penny 70)
C[+nas]C[+bil,-son]L[+lat] > { CCL[-lat,+pal], CCL } : 77"""') palatalisation des liquides; dans quelques cas, le groupe reste intact (Penny 70)
C[+nas]C[+vel,+ocl,-son]L[+lat] > { CCL[-lat,+pal], CCL } : 77"""") palatalisation des liquides; dans quelques cas, le groupe reste intact (Penny 70)
C[+nas]C[+ldent,+fric,-son]L[+lat] > { CCL[-lat,+pal], CCL } : 77""""') palatalisation des liquides; dans quelques cas, le groupe reste intact (Penny 70)
C[+nas]C[+ldent,+fric,-son]L[+lat] > { CCL[-lat,+pal], CCL } : 77""""") palatalisation des liquides; dans quelques cas, le groupe reste intact (Penny 70)
C1[-son]L[+pal] > &1 L : 78a) assimilation consonantique
C1[+vel,+son]L[+lat] > &1 L : 78b) assimilation consonantique
j1 C[+pal,+son] > &1 C : 79i) assimilation de yod
C[+pal,+son] j1 > C &1 : 79ii) assimilation de yod
@#.O1.&|.A2[+ton].&|.V3.&# > { @.O1.&.A2.&.V3.&, @.a&1.&.A2.&.V3.& } : 79.5) assimilation, tendance (ex. novaja > navaja)
V[+moy,-ton].&|.CGV[+ton] > { V.&.CGV, V[+haut].&.CGV } : 80i) le yod / wau agit sur la syllabe précédente (tendance)
V[+moy,-ton].&|.LGV[+ton] > { V.&.LGV, V[+haut].&.LGV } : 80ii) le yod / wau agit sur la syllabe précédente (tendance)
@# j1 V[+ant,-ton] > @ &1 V : 81') assimilation de yod
V j1 V[+ant,+haut,+ton] > V &1 V : 81") assimilation de yod
j1j2 > j1&2 : 81.5) fusion des deux yods
@# j1 > { @ C[+pal,+fric,+son]&1, @j1 } : 82ii) perte de yod ou transformation en affriquée
C1[+nas,+alv]j2 > C1 C[+dent,+afr,+sourd]&2 : 82iii) transformation de yod en affriquée
?[-cons]rj1 > ?rC[+dent,+afr,+sourd]&1 : 82iv) transformation de yod en affriquée
C1[+retro]C2[+retro,-son] > &1C[+pal,+afr,+son]&2 : 83) transformation de rétroflexes en yod
C[+nas]L[+pal] > C L[+cons,+pal,+afr,+sourd] : 84i) les liquides palatales se transforment en affriquées
C[+alv,+fric]L[+pal] > C L[+cons,+pal,+afr,+sourd] : 84ii) les liquides palatales se transforment en affriquées
@#L[+pal]V > { @LV, @L[+cons,+pal,+afr,+sourd]V } : 84iii) dans quelques cas, #£V > #¶V (Penny 71)
m1C[+cons,+pal,+afr,+sourd] > n&1C : 84.5) assimilation de m
; règle 85 => 65.7
@[+verbe,+impf,-are]#*Vß1A > @*V&1A : 85.51) chute de ß dans les imparfaits des verbes
@[+verbe,+impf,-are]#*E1[+ton]|A > @*I[+ferm]&1[+ton]A : 85.52) fermeture de la voyelle en hiatus (imparfait)
ñ1 I V > n&1 I V : 85.53) dépalatalisation de ñ devant i en hiatus
V1[+moy,+ant] j2 V3 > V1| V[+moy,+ant] &2| V3 : 86a') vocalisation du yod
V1[+moy,+ant] j2 > V1| V[+moy,+ant] &2 : 86a") vocalisation du yod
V1[+moy,+post] w2 V3 > V1| V[+moy,+post]| &2| V3 : 86b') vocalisation du wau
V1[+moy,+post] w2!| > V1| V[+moy,+post] &2!| : 86b") vocalisation du wau
V1[+moy,+post] w2| > V1| V[+moy,+post] &2| : 86b"') vocalisation du wau
I1 j2 > I1| I1[-ton] &2 : 86c) vocalisation du yod
E1|E2# > E1!|&2 : 87i) fusion vocalique
E1|E2[+ton]| > E2[+ton]&1| : 87ii) fusion vocalique
E1|E2[+ton]!| > E2[+ton]&1!| : 87iii) fusion vocalique
E1[+ton]|E2 > E1!|&2 : 87iv) fusion vocalique
E1|E2 > E1!|&2 : 87v) fusion vocalique
O1|O2 > O1!|&2 : 87vi) fusion vocalique
I1|I2 > I1!|&2 : 87vii) fusion vocalique
?[+cons,+liq,+svoc]E|!+I2[+ton]?[+cons,+liq,+svoc] > ?E[+ferm,+ton]!|j&2? : 87.1) déplacement de l'accent sur la syllabe plus ouverte, yodisation de i
V[+ouv,+ferm,-ton] > V[-ouv] : 87.2) neutralisation de la distinction [+ouv]/[+ferm] dans les voyelles atones
Vn|rV > { VndrV, Vr|n!|V, VnrV } : 87.6) groupe secondaire n'r: méthatèse ou insertion de la consonne épenthétique d ou évolution zéro
VC[+dent,+afr,-son]V > V C[+son] V : 88) sonorisation des affriquées dentales
@[+verbe,-ser,+iii,+sg,+parf]#*V[+ton].&|.E1t# > @*V.&.o&1t : 88.5) terminaison analogique (verbes)
? C1[+dent,+ocl]# > ?!|&1 : 89) chute des dentales finales
@#AC1[+dent]|+ > @A&1 : 89.1) chute des dentales dans le préfixe ad-
@[+verbe,-ser,+subj]#*V[+ton,+post,+cent]|V# > { @*VV, @*VjV } : 89.31) insertion d'un yod épentéthique, tendance (verbes)
@[+verbe,-ser,+subj]#*V|N[+pal]V# > { @*VNV, @*V!|N[+alv]|gV } : 89.32) insertion d'un g épenthétique, tendance (verbes)
@[+verbe,-ser,+subj]#*V|jV# > { @*VjV, @*V!|j|ÔV } : 89.33) insertion d'un Ô épenthétique, tendance (verbes)
b1# > &1 : 89.5) chute de b final
@[+verbe,+impf]#*í[+ton]a# > { @*ía, @*í[-ton]a[+ton] } : 89.71) déplacement de l'accent dans les imparfait des verbes (tendance abandonnée plus tard)
@[+verbe,+impf]#*ía1[+ton]# > @*íé[+ton]&1 : 89.72) assimilation de a (forme irrégulière de l'imparfait)
@[+verbe,+impf]#*í1|E[+ton]# > @*j&1!|E : 89.73) i en hiatus passe à j (forme irrégulière de l'imparfait au moyen âge)
C1[+alv,+fric,-son]C[+afr,-son] > &1 C : 90) assimilation consonantique
Vngn1V > Vn|g!|r!|&1V : 90.5) dissimilation
@[-procl,-encl,+verbe]#*?|LV1[+ant,-ton]# > @* ?!| L&1 : 91i) apocope définitive de la voyelle finale dans les verbes
@[-verbe]#*?[+voc,+liq]|C[+alv,+dent,+fric]V1[+ant,-ton]# > @[+apoc]* ?!| C&1 : 91ii') apocope de la voyelle finale
@[-verbe]#*?[+voc,+liq]|C[-bil] V1[+ant,-ton]# > @* ?!| C&1 : 91ii') apocope de la voyelle finale
@[+verbe]#*?[+voc,+liq]|C[-bil] V1[+ant,-ton]# > @[+apoc]* ?!| C&1 : 91ii") apocope de la voyelle finale
@[-verbe]# * V| L V1[+ant,-ton]# > @* V!| L&1 : 91iii) apocope définitive de la voyelle finale
@[+rec,+verbe,+fut,+i,+sg]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#é[+ton]# : 91.51) formation synthétique du futur
@[+rec,+verbe,+fut,+ii,+sg]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#a[+ton]Ç# : 91.52) formation synthétique du futur
@[+rec,+verbe,+fut,+iii,+sg]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#a[+ton]# : 91.53) formation synthétique du futur
@[+rec,+verbe,+fut,+i,+pl]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#é[+ton]|moÇ# : 91.54) formation synthétique du futur
@[+rec,+verbe,+fut,+ii,+pl]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#é[+ton]jÇ# : 91.55) formation synthétique du futur
@[+rec,+verbe,+fut,+iii,+pl]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#a[+ton]n# : 91.56) formation synthétique du futur
@[+rec,+verbe,+cond,+i,+sg]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#í[+ton]|a# : 91.61) formation synthétique du conditionnel
@[+rec,+verbe,+cond,+ii,+sg]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#í[+ton]|aÇ# : 91.62) formation synthétique du conditionnel
@[+rec,+verbe,+cond,+iii,+sg]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#í[+ton]|a# : 91.63) formation synthétique du conditionnel
@[+rec,+verbe,+cond,+i,+pl]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#í[+ton]|a|moÇ# : 91.64) formation synthétique du conditionnel
@[+rec,+verbe,+cond,+ii,+pl]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#í[+ton]|ajÇ# : 91.65) formation synthétique du conditionnel
@[+rec,+verbe,+cond,+iii,+pl]#*V[+ton]r# > @[-rec]#*V[-ton,-ouv]|r!#í[+ton]|an# : 91.66) formation synthétique du conditionnel
@[+verbe,+cond,+fut]#.V1|C[+dent]V2[-bas]|rV3[+ton] > { @#.V1C&2!|rV3, @.V1CV2rV3 } : 91.71) syncope dans les conditionnels / futurs, tendance
@[+verbe,+cond,+fut]#.V1|rV2[-bas]|rV3[+ton] > @#.V1&2r[+long]V3 : 91.72) syncope dans les conditionnels / futurs
C[+dent,+son,-afr,-fric] C[+son,-nas] > C[+afr] C : 92) les dentales sonores se transforment en affriquées
C[+afr,+son]| > C[+sourd] : 93i) assourdissement des consonnes implosives
C[+afr,+son]# > C[+sourd] : 93ii) assourdissement des consonnes implosives
@[-procl,-encl]#*V1[+post,+haut,+ton]!| j2 > @*w&1 V[+ant,+haut,+ton,+ferm]&2 : 94i) déplacement de l'accent
@[-procl,-encl]#*V1[+post,+haut]!| j2 > @*w&1 V[+ant,+haut]&2 : 94ii) déplacement de l'accent
w V[+ant,+haut,+ton] > { wV, wV[+moy] } : 95) ouverture de i, *tendance
@[+procl,+encl]#L[+pal]V > @L[-pal,+lat]V : 96.5) dépalatalisation de la consonne palatale initiale dans les mots proclitiques / enclitiques
@#.V[+ton]m1# > @.Vn&1 : 97.51) m final passe à n dans del monosyllabes
; *******************************************************************
; *** castillan médiéval (siècles XIII-XIV) ***
; *******************************************************************
1300: C[+alv,+nas] C[+bil,+nas] > C[+liq,+lat] C : test ;{ C[+liq,+vibr] C, C[+liq,+lat] C } : 97ii) dissimilation de groupes consonantique secondaires
Vm1|C[+dent]V > Vn&1CV : 97.1) assimilation du m
VC[+nas,+alv]|C[+bil]V > VC[+bil]CV : 97.2) assimilation du n
@#n1.&|.n|? > { @n1.&.n?, @l&1.&.n? } : 97.3) dissimilation de n-n, tendance
@[-adv]#*Vm|pr1V > { @*Vmpr1V, @*Vmpl&1V } : 97.6) confusion de r/l, tendance
V|r1V|C[+bil,+vel,-nas]l2V > Vl&1VCr&2V : 97.7) métathèse à distance
C1[+bil,+dent,+bil,+nas]L > C1C1[+ocl]!|L : 98) insertion de consonnes épenthetiques
@[-procl,-encl]#*?[+cons,+liq]C[+cons,+dent,+alv]# > @* ?| C!# V[+ant,+moy]# : 99a') restriction de l'apocope
@[-procl,-encl]#*VC[+cons,+dent,+alv,+ocl]# > @* V| C!# V[+ant,+moy]# : 99a") restriction de l'apocope
@[-procl,-encl]#*?C[+bil,+pal,+vel]# > @[-apoc]* ?| C!# V[+ant,+moy]# : 99b') restriction de l'apocope
@[-procl,-encl]#*?C[+afr]# > { @[-apoc]*?C, @[-apoc]*?|C!#V[+ant,+moy]# } : 99b") restriction de l'apocope dans certains cas (notamment les verbes)
@[+apoc]#*?C[+dent,+alv]# > { @[-apoc]*?C, @[-apoc]*?|C!# V[+ant,+moy]# } : 99c) restriction de l'apocope, tendance
C[+pal,-retro,-afr]| > C[+alv] : 99.51) <= 96i) dépalatalisation des consonnes implosives
C[+pal,-retro,-afr]# > C[+alv] : 99.52) <= 96ii) dépalatalisation des consonnes implosives
L[+pal]| > L[-pal,+lat] : 99.53) <= 96iii) dépalatalisation des consonnes implosives
L[+pal]# > L[-pal,+lat] : 99.54) <= 96iv) dépalatalisation des consonnes implosives
j1e2[+ton]L[+pal]V > &1í[+ton]&2LV : 100i) réduction de la diphtongue palatale
j1e2[+ton]C[+alv,+fric]C > { &1í[+ton]&2CC, j1e2CC } : 100ii) réduction de la diphtongue palatale, *tendance (pas dans siesta, fiesta)
j1e2[+ton]C[+bil,+son]j > &1í[+ton]&2Cj : 100iii) réduction de la diphtongue palatale
@#j1V > @&1V : 101i) consonantisation de yod
?[-afr]|j1V > ?&1V : 101ii) consonantisation de yod
@#C[+bil,+aprox] > @ C[+ocl] : 102i) occlusion de la bilabiale
?|C[+bil,+aprox] > ? C[+ocl] : 102ii) occlusion de la bilabiale
C1[+bil,+ocl,+fric,+aprox]C > w&1 C : 103i) vocalisation de b
L1[+lat]C > { w&1 C, L1 C } : 103ii) vélarisation de l
V[+ton,+cent,+ant,-haut]w1 > V[-ferm]u[+ton]&1 : 103.31) vocalisation de w
V[-ton,+cent,+ant,-haut]w1 > V[-ferm]u&1 : 103.32) vocalisation de w
I1[+ton]w2 > j&1u[+ton]&2 : 103.33) vocalisation de w
I1[-ton]w2 > j&1u&2 : 103.34) vocalisation de w
Ow1 > { O[+haut,-ferm]w1, O&1 } : 103.35) assimilation du wau ou fermeture de la voyelle précédente, tendances
Uw1 > U&1 : 103.36) assimilation du wau
Vl1|.?[-vibr]V > { Vl1.?V, Vr&1.?V } : 103.5) confusion de l/r en position implosive, tendance (ex. sulcu > surco)
h1 > &1 : 104) perte de l'aspiration (< résultat de f aspiré)
V C[+ocl,+son] V > V C[+aprox] V : 105i) affaiblissement des sonores intervocaliques
V L!+ C[+ocl,+son] V > V L C[+aprox] V : 105ii) affaiblissement des sonores intervocaliques
V C[+ocl,+son] L V > V C[+aprox] L V : 105iii) affaiblissement des sonores intervocaliques
V L!+ C[+ocl,+son] L V > V L C[+aprox] L V : 105iv) affaiblissement des sonores intervocaliques
V C[+ocl,+son] j V > V C[+aprox] j V : 105v) affaiblissement des sonores (*)
V C[+ocl,+son] w A > V C[+aprox] w A : 105vi) affaiblissement des sonores (*)
fLw1e[+ton] > fL&1e : 106i) chute de w après fL
w1e[+ton]C[+bil,+fric,+aprox]LV > &1eCLV : 106ii) chute de w
; *******************************************************************
; *** espagnol moderne (siècles XV-XX) ***
; *******************************************************************
1500: @#wV[+ton] > @ g w V : 107) prothèse de la vélaire
@[+verbe]*V[+ton]|C1[+dent,+fric]VC > @*V|&1VC : 108) chute des fricatives secondaires (verbes)
@[+verbe]*a[+ton]|e1C > { @*a!|j&1C, @*a!|&1C } : 109) fermeture ou assimilation de la deuxième voyelle
V C[+dent,+ocl,+son]| > V C[+aprox] : 110i) affaiblissement de la dentale implosive
V C[+dent,+ocl,+son]# > V C[+aprox] : 110ii) affaiblissement de la dentale implosive
@[+verbe]#*V[+ton]|C1[+dent,+aprox]E2C[+alv]# > @*V!|&1j&2C : 111.01) évolution de la terminaison verbale
@[+verbe]#*V[+ton].&|.V|C1[+dent,+fric,+aprox]V2[+ant,+moy]C > @*V.&.V!|&1&2jC : 111.02) évolution de la terminaison verbale
C[+dent,+son,+fric,-nas] > C[+sourd,+alv] : 112i) assourdissement
C[+dent,+afr,+son] > C[+sourd] : 112ii) assourdissement
C[+pal,+son,-aprox,-nas] > C[+sourd] : 112iii) assourdissement
C[+pal,+fric,-son] > C[+vel] : 113) vélarisation de la fricative palatale
C[+dent,+afr,-son] > C[+ident,+fric] : 114) avancement articulatoire des dentales
@#C1[+vel,+ocl,+son]wV[+ant,+moy,+ton] > @&1wV : 115) perte de la vélaire initiale
V[+ton]C1[+dent,+aprox]V > { VC1V, V&1V } : 116i) amuïssement éventuel des fricatives sonores finales
C1[+dent,+aprox]# > { C1, &1 } : 116ii) amuïssement éventuel des fricatives sonores finales
L1[+pal]j2 > &1&2 : 117i) yodisation de la liquide palatale
L1[+pal] > &1 : 117ii) yodisation de la liquide palatale
1900: @[+procl,+encl] > @[-procl] : 118.1) éliminer les informations grammaticales (règle technique)
@[+arab,+germ,+celt] > @[-arab] : 118.2) éliminer les informations grammaticales (règle technique)
@[+verbe,+subst,+adj,+prep,+pron,+conj,+adv,+reste] > @[-verbe] : 118.3) éliminer les informations grammaticales (règle technique)
@[+dep] > @[-dep] : 118.4) éliminer les informations grammaticales (règle technique)
@[+inf,+ger,+part,+imper] > @[-inf] : 118.5) éliminer les informations grammaticales (règle technique)
@[+parf,+impf,+pres,+fut,+cond] > @[-parf] : 118.6) éliminer les informations grammaticales (règle technique)
@[+are,+eere,+ire,+ere,+autre,+ser] > @[-are] : 118.7) éliminer les informations grammaticales (règle technique)
@[+sg,+pl] > @[-sg] : 118.8) éliminer les informations grammaticales (règle technique)
@[+i,+ii,+iii] > @[-i] : 118.9) éliminer les informations grammaticales (règle technique)
@[+gra,+gro,+gru,+gre,+grk,+gri,+grm,+grnd,+irr] > @[-gra] : 118.10) éliminer les informations grammaticales (règle technique)
@[+nom,+gen,+dat,+acc,+abl,+vok] > @[-nom] : 118.11) éliminer les informations grammaticales (règle technique)
@[+m,+f,+n,+mf] > @[-m] : 118.12) éliminer les informations grammaticales (règle technique)
@[+dim,+augm] > @[-dim] : 118.13) éliminer les informations grammaticales (règle technique)
@[+amalg] > @[-amalg] : 118.14) éliminer les informations grammaticales (règle technique)
@[+dieu] > @[-dieu] : 118.15) éliminer les informations grammaticales (règle technique)
@[+poss,+card,+ord] > @[-poss] : 118.16) éliminer les informations grammaticales (règle technique)
@[+invar] > @[-invar] : 118.17) éliminer les informations grammaticales (règle technique)
@[+comp,+superl] > @[-comp] : 118.18) éliminer les informations grammaticales (règle technique)
@[+us] > @[-us] : 118.19) éliminer les informations grammaticales (règle technique)
@[+subj] > @[-subj] : 118.20) éliminer les informations grammaticales (règle technique)
@[+apoc] > @[-apoc] : 118.21) éliminer les informations grammaticales (règle technique)
?+ > ?!+ : éliminer les frontières de morphèmes (règle technique)
V?[+cons,+liq]|V > { V?V, V|?!|V } : correction de la structure syllabique (après élimination des frontières de morphèmes), tendance
@endrules
| Retour à la page principale | << Chapitre précédent | Chapitre suivant >> |